source: projects/vine-manual-build/trunk/web.xsl.in @ 4525

Revision 4525, 10.2 KB checked in by yasumichi, 13 years ago (diff)

公式サイト用の修正部分を取り込み

Line 
1<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version='1.0'>
2
3        <xsl:import href="/usr/share/xml/gnome/xslt/docbook/html/db2html.xsl"/>
4       
5        <xsl:param name="db.chunk.chunk_top">0</xsl:param>
6        <xsl:param name="db.chunk.max_depth">2</xsl:param>
7
8        <!-- Q&A のスタイル変更 -->
9        <xsl:template match="question" mode="label.markup">
10                <xsl:text>Q</xsl:text>
11                <xsl:number level="multiple" count="qandaentry" format="1"/>
12        </xsl:template>
13        <xsl:template match="answer" mode="label.markup">
14                <xsl:text>A</xsl:text>
15                <xsl:number level="multiple" count="qandaentry" format="1"/>
16        </xsl:template>
17
18        <!--xsl:param name=""></xsl:param>
19        <xsl:param name=""></xsl:param-->
20        <!-- head 要素に script を追加 -->
21        <xsl:template name="db2html.division.head.extra">
22<script type="text/javascript"><xsl:comment>
23    var _gaq = _gaq || [];
24    _gaq.push(['_setAccount', 'UA-156959-1']);
25    _gaq.push(['_trackPageview']);
26    (function() {
27      var ga = document.createElement('script'); ga.type = 'text/javascript'; ga.async = true;
28      ga.src = ('https:' == document.location.protocol ? 'https://ssl' : 'http://www') + '.google-analytics.com/ga.js';
29      var s = document.getElementsByTagName('script')[0]; s.parentNode.insertBefore(ga, s);
30    })();
31//</xsl:comment>
32</script>
33        </xsl:template>
34
35        <!-- 上部のナビゲーションバーを変更 -->
36        <xsl:template name="db2html.division.top">
37                <div id="toplogo">
38                        <img src="@IMAGEDIR@/logo-vinelinux-nostring.png" alt="Vine Linux" />
39                        <div id="toplogo-title">
40                                <h1><strong>V</strong>ine<strong>L</strong>inux オンラインマニュアル</h1>
41
42                                <p>- コンパクトで軽量な日本語ディストリビューション -</p>
43                        </div>
44                </div>
45                <div id="menu">
46                        <ul id="main">
47                                <li><a class="left" href="/">ホーム</a></li>
48                                <li><a href="/aboutvinelinux.html">Vine Linux</a></li>
49                                <li><a href="/download.html">ダウンロード</a></li>
50                                <li><a href="/documentation.html">ドキュメント</a></li>
51                                <li><a href="/books.html">書籍</a></li>
52                                <li><a href="/ml.html">ML</a></li>
53                                <li><a href="/errata.html">エラッタ情報</a></li>
54                                <li><a href="/bts.html">バグ情報</a></li>
55                                <li><a href="/projects.html">プロジェクト</a></li>
56                                <li><a href="http://planet.vinelinux.org/">開発者ブログ</a></li>
57                                <li><a href="http://trac.vinelinux.org/">Wiki</a></li>
58                        </ul>
59                </div>
60        </xsl:template>
61
62        <!-- db2html.division.html の上書き -->
63<xsl:template name="db2html.division.html">
64  <xsl:param name="node" select="."/>
65  <xsl:param name="info" select="/false"/>
66  <xsl:param name="template"/>
67  <xsl:param name="depth_of_chunk">
68    <xsl:call-template name="db.chunk.depth-of-chunk">
69      <xsl:with-param name="node" select="$node"/>
70    </xsl:call-template>
71  </xsl:param>
72  <xsl:param name="prev_id">
73    <xsl:choose>
74      <xsl:when test="$depth_of_chunk = 0">
75        <xsl:if test="$info and $db.chunk.info_chunk">
76          <xsl:value-of select="$db.chunk.info_basename"/>
77        </xsl:if>
78      </xsl:when>
79      <xsl:otherwise>
80        <xsl:call-template name="db.chunk.chunk-id.axis">
81          <xsl:with-param name="node" select="$node"/>
82          <xsl:with-param name="axis" select="'previous'"/>
83          <xsl:with-param name="depth_in_chunk" select="0"/>
84          <xsl:with-param name="depth_of_chunk" select="$depth_of_chunk"/>
85        </xsl:call-template>
86      </xsl:otherwise>
87    </xsl:choose>
88  </xsl:param>
89  <xsl:param name="next_id">
90    <xsl:call-template name="db.chunk.chunk-id.axis">
91      <xsl:with-param name="node" select="$node"/>
92      <xsl:with-param name="axis" select="'next'"/>
93      <xsl:with-param name="depth_in_chunk" select="0"/>
94      <xsl:with-param name="depth_of_chunk" select="$depth_of_chunk"/>
95    </xsl:call-template>
96  </xsl:param>
97  <xsl:variable name="prev_node" select="key('idkey', $prev_id)"/>
98  <xsl:variable name="next_node" select="key('idkey', $next_id)"/>
99  <!-- FIXME -->
100  <html>
101    <head>
102      <title>
103        <xsl:variable name="title">
104          <xsl:call-template name="db.title">
105            <xsl:with-param name="node" select="$node"/>
106          </xsl:call-template>
107        </xsl:variable>
108        <xsl:value-of select="normalize-space($title)"/>
109      </title>
110      <xsl:if test="string($prev_id) != ''">
111        <link rel="previous">
112          <xsl:attribute name="href">
113            <xsl:call-template name="db.xref.target">
114              <xsl:with-param name="linkend" select="$prev_id"/>
115              <xsl:with-param name="target" select="$prev_node"/>
116              <xsl:with-param name="is_chunk" select="true()"/>
117            </xsl:call-template>
118          </xsl:attribute>
119          <xsl:attribute name="title">
120            <xsl:call-template name="db.title">
121              <xsl:with-param name="node" select="$prev_node"/>
122            </xsl:call-template>
123          </xsl:attribute>
124        </link>
125      </xsl:if>
126      <xsl:if test="string($next_id) != ''">
127        <link rel="next">
128          <xsl:attribute name="href">
129            <xsl:call-template name="db.xref.target">
130              <xsl:with-param name="linkend" select="$next_id"/>
131              <xsl:with-param name="target" select="$next_node"/>
132              <xsl:with-param name="is_chunk" select="true()"/>
133            </xsl:call-template>
134          </xsl:attribute>
135          <xsl:attribute name="title">
136            <xsl:call-template name="db.title">
137              <xsl:with-param name="node" select="$next_node"/>
138            </xsl:call-template>
139          </xsl:attribute>
140        </link>
141      </xsl:if>
142      <xsl:if test="/*[1] != $node">
143        <link rel="top">
144          <xsl:attribute name="href">
145            <xsl:call-template name="db.xref.target">
146              <xsl:with-param name="linkend" select="/*[1]/@id"/>
147              <xsl:with-param name="target" select="/*[1]"/>
148              <xsl:with-param name="is_chunk" select="true()"/>
149            </xsl:call-template>
150          </xsl:attribute>
151          <xsl:attribute name="title">
152            <xsl:call-template name="db.title">
153              <xsl:with-param name="node" select="/*[1]"/>
154            </xsl:call-template>
155          </xsl:attribute>
156        </link>
157      </xsl:if>
158      <xsl:call-template name="db2html.css">
159        <xsl:with-param name="css_file" select="$depth_of_chunk = 0"/>
160      </xsl:call-template>
161      <xsl:call-template name="db2html.division.head.extra"/>
162    </head>
163    <body>
164      <xsl:call-template name="db2html.division.top">
165        <xsl:with-param name="node" select="$node"/>
166        <xsl:with-param name="info" select="$info"/>
167        <xsl:with-param name="template" select="$template"/>
168        <xsl:with-param name="depth_of_chunk" select="$depth_of_chunk"/>
169        <xsl:with-param name="prev_id" select="$prev_id"/>
170        <xsl:with-param name="next_id" select="$next_id"/>
171        <xsl:with-param name="prev_node" select="$prev_node"/>
172        <xsl:with-param name="next_node" select="$next_node"/>
173      </xsl:call-template>
174      <div id="page"><!-- vine 用追加部分 -->
175      <xsl:variable name="sidebar">
176        <xsl:call-template name="db2html.division.sidebar">
177          <xsl:with-param name="node" select="$node"/>
178          <xsl:with-param name="info" select="$info"/>
179          <xsl:with-param name="template" select="$template"/>
180          <xsl:with-param name="depth_of_chunk" select="$depth_of_chunk"/>
181          <xsl:with-param name="prev_id" select="$prev_id"/>
182          <xsl:with-param name="next_id" select="$next_id"/>
183          <xsl:with-param name="prev_node" select="$prev_node"/>
184          <xsl:with-param name="next_node" select="$next_node"/>
185        </xsl:call-template>
186      </xsl:variable>
187      <xsl:copy-of select="$sidebar"/>
188      <div>
189        <xsl:attribute name="class">
190          <xsl:text>body</xsl:text>
191          <xsl:if test="$sidebar != ''">
192            <xsl:text> body-sidebar</xsl:text>
193          </xsl:if>
194        </xsl:attribute>
195        <xsl:choose>
196          <xsl:when test="$template = 'info'">
197            <xsl:call-template name="db2html.info.div">
198              <xsl:with-param name="node" select="$node"/>
199              <xsl:with-param name="info" select="$info"/>
200              <xsl:with-param name="depth_of_chunk" select="$depth_of_chunk"/>
201            </xsl:call-template>
202          </xsl:when>
203          <xsl:otherwise>
204            <xsl:apply-templates select="$node">
205              <xsl:with-param name="depth_in_chunk" select="0"/>
206              <xsl:with-param name="depth_of_chunk" select="$depth_of_chunk"/>
207            </xsl:apply-templates>
208          </xsl:otherwise>
209        </xsl:choose>
210      </div>
211      <xsl:call-template name="db2html.division.bottom">
212        <xsl:with-param name="node" select="$node"/>
213        <xsl:with-param name="info" select="$info"/>
214        <xsl:with-param name="template" select="$template"/>
215        <xsl:with-param name="depth_of_chunk" select="$depth_of_chunk"/>
216        <xsl:with-param name="prev_id" select="$prev_id"/>
217        <xsl:with-param name="next_id" select="$next_id"/>
218        <xsl:with-param name="prev_node" select="$prev_node"/>
219        <xsl:with-param name="next_node" select="$next_node"/>
220      </xsl:call-template>
221<!-- 追加のフッタ -->
222<div id="ads-footer">
223<p class="byline"></p>
224<script type="text/javascript"><xsl:comment>
225google_ad_client = "pub-0334540465096658";
226/* vinelinux bottom wide */
227google_ad_slot = "6992354029";
228google_ad_width = 728;
229google_ad_height = 90;
230//</xsl:comment>
231</script>
232<script type="text/javascript"
233src="http://pagead2.googlesyndication.com/pagead/show_ads.js">
234</script>
235</div>
236</div><!-- page -->
237<div id="footer">
238    <div id="footmenu">
239        <a href="/projectvine.html">Project Vine について</a> |
240        <a href="/copyright.html">このサイトについて</a> |
241        <a href="/privacypolicy.html">プライバシーポリシー</a> |
242        <a href="/donation.html">ご協力・ご寄付について</a> |
243        <a href="http://trac.vinelinux.org/wiki/Vine6/Roadmap">ロードマップ</a>
244    </div>
245    <p><a href="/copyright.html">
246       Copyright (C)1998-2011 Project Vine, All Rights Reserved.</a></p>
247</div>
248
249    </body>
250  </html>
251</xsl:template>
252
253        <!-- スタイルシートを独自のものに変更 -->
254        <xsl:template name="db2html.css">
255                <link rel="stylesheet" type="text/css" href="@CSSFILE@"/>
256        </xsl:template>
257</xsl:stylesheet>
258
Note: See TracBrowser for help on using the repository browser.