source: projects/setup/trunk/csh.cshrc @ 8718

Revision 8718, 1.6 KB checked in by daisuke, 10 years ago (diff)

update to 2.9.0

Line 
1# /etc/cshrc
2#
3# csh configuration for all shell invocations.
4
5# By default, we want this to get set.
6# Even for non-interactive, non-login shells.
7# Current threshold for system reserved uid/gids is 200
8# You could check uidgid reservation validity in
9# /usr/share/doc/setup-*/uidgid file
10if ($uid > 199 && "`id -gn`" == "`id -un`") then
11    umask 002
12else
13    umask 022
14endif
15
16if ($?prompt) then
17  if ($?tcsh) then
18    set promptchars='$#'
19    set prompt='[%n@%m %c]%# '
20    # make completion work better by default
21    set autolist
22  else
23    set prompt=\[$user@`hostname -s`\]\$\
24  endif
25endif
26
27if ( $?tcsh ) then
28        bindkey "^[[3~" delete-char
29endif
30
31bindkey "^R" i-search-back
32set echo_style = both
33set histdup = erase
34set savehist = (1024 merge)
35
36if ($?prompt) then
37  if ($?TERM) then
38    switch($TERM)
39      case xterm*:
40        if ($?tcsh) then
41          set prompt='%{\033]0;%n@%m:%c\007%}[%n@%m %c]%# '
42        endif
43        breaksw
44      case screen:
45        if ($?tcsh) then
46          set prompt='%{\033k%n@%m:%c\033\\%}[%n@%m %c]%# '
47        endif
48        breaksw
49      default:
50        breaksw
51    endsw
52  endif
53endif
54
55setenv MAIL "/var/spool/mail/$USER"
56
57# Check if we aren't a loginshell and do stuff if we aren't
58if (! $?loginsh) then
59    if ( -d /etc/profile.d ) then
60        set nonomatch
61        foreach i ( /etc/profile.d/*.csh )
62            if ( -r "$i" ) then
63                if ($?prompt) then
64                    source "$i"
65                else
66                    source "$i" >&/dev/null
67                endif
68            endif
69        end
70        unset i nonomatch
71    endif
72endif
Note: See TracBrowser for help on using the repository browser.